	.even
title:
	mov	r1,-(sp)		/save r1
	tst	token2			/"/" present?
	bne	1f
	mov	$1,r0
	sys	write; j.title; 128.	/write title
	br	9f
1:
	mov	$j.title,r0
	mov	$j.title+128.,r1
	movb	$1,cflag		/set core record changed
1:
	clrb	(r0)+			/null-out title
	cmp	r0,r1
	blo	1b
	tst	token3			/"*" present?
	bne	9f			/branch if yes
	mov	token2,r0
	inc	r0
	mov	$j.title,r1
	cmp	r0,lastchar		/"/<nl>"?
	beq	9f			/branch if yes
2:
	movb	(r0)+,(r1)+		/change title
	cmp	r0,lastchar
	bhis	9f
	cmp	r1,$j.title+128.
	blo	2b
	cmpb	(r0),$'\n		/129th char <nl>?
	beq	9f
	jsr	r5,mesg
	<TITLE TRUNCATED TO 128 CHARS\n\0>
	.even
9:
	mov	(sp)+,r1		/restore r1
	rts	r5


number:
	tst	token2			/"/" present?
	beq	1f			/branch if not
	jsr	r5,mesg
	<3ILLEGAL IN-CORE JOB NO. CHANGE ATTEMPTED4\n\0>
	.even
	rts	r5
1:
	mov	j.number,temp		/delete various flag bits
	bic	$177776,temp
	mov	j.number+2,temp+2
	jsr	r5,itoa			/write job no.
	temp
	bitb	$2,j.number		/"S" number?
	beq	1f			/branch if not
	jsr	r5,mesg
	<-S\0>
	.even
1:
	rts	r5
